message(STATUS "CMAKE_CXX_COMPILER_ID: ${CMAKE_CXX_COMPILER_ID}")
message(STATUS "CMAKE_SYSTEM_NAME: ${CMAKE_SYSTEM_NAME}")
message(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")

if(DEFINED CMAKE_TOOLCHAIN_FILE)
  message(STATUS ">>> CMAKE_TOOLCHAIN_FILE: ${CMAKE_TOOLCHAIN_FILE}")
endif()

# MinGW/MSYS2 静态链接
if(MINGW)
  add_link_options(-static -static-libgcc -static-libstdc++)
elseif(UNIX AND NOT APPLE) # Linux 静态链接
  add_link_options(-static-libgcc -static-libstdc++)
endif()

if(WIN32)
  set(CMAKE_FIND_LIBRARY_SUFFIXES ".a" ".lib" ".dll.a")
else()
  set(CMAKE_FIND_LIBRARY_SUFFIXES ".a" ".so")
endif()

find_package(glaze CONFIG REQUIRED)
find_package(spdlog CONFIG REQUIRED)
find_package(fmt CONFIG REQUIRED)
find_package(Taskflow CONFIG REQUIRED)
find_package(tree-sitter CONFIG REQUIRED)

if(UNIX AND NOT APPLE)
  find_package(Threads REQUIRED)
endif()

if(NOT TARGET spdlog::spdlog_header_only)
  message(WARNING "spdlog header-only target not found, using shared library")
endif()
if(NOT TARGET fmt::fmt-header-only)
  message(WARNING "fmt header-only target not found, using shared library")
endif()

set(SOURCES
    main.cpp
    utils/args_parser.cpp
    utils/string.cpp
    core/dispacther.cpp
    core/server.cpp
    scheduler/async_executor.cpp
    language/ast/deserializer.cpp
    language/ast/detail.cpp
    language/ast/tree_sitter_utils.cpp
    language/symbol/builder.cpp
    language/symbol/index/location.cpp
    language/symbol/index/scope.cpp
    language/symbol/graph/call.cpp
    language/symbol/graph/inheritance.cpp
    language/symbol/graph/reference.cpp
    language/symbol/store.cpp
    language/symbol/table.cpp
    language/keyword/repo.cpp
    provider/base/bootstrap.cpp
    provider/base/interface.cpp
    provider/initialize/initialize.cpp
    provider/initialized/initialized.cpp
    provider/text_document/did_open.cpp
    provider/text_document/did_change.cpp
    provider/text_document/did_close.cpp
    provider/text_document/completion.cpp
    # provider/text_document/semantic_tokens.cpp
    provider/shutdown/shutdown.cpp
    provider/exit/exit.cpp
    provider/cancel_request/cancel_request.cpp
    provider/trace/set_trace.cpp
    provider/completion_item/resolve.cpp
    service/base/bootstrap.cpp
    service/utils/text_coordinates.cpp
    service/detail/document/text_document.cpp
    service/detail/symbol/conversion.cpp
    service/detail/symbol/utils.cpp
    service/detail/symbol/repository/editing.cpp
    service/detail/symbol/repository/workspace.cpp
    service/detail/symbol/repository/system.cpp
    service/document.cpp
    service/symbol.cpp
    service/parser.cpp
    tree-sitter/parser.c
    tree-sitter/scanner.c)

add_executable(${PROJECT_NAME} ${SOURCES})
target_include_directories(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})

target_compile_definitions(${PROJECT_NAME} PRIVATE SPDLOG_HEADER_ONLY
                                                   FMT_HEADER_ONLY)

target_link_libraries(
  ${PROJECT_NAME}
  PRIVATE glaze::glaze Taskflow::Taskflow spdlog::spdlog_header_only
          fmt::fmt-header-only tree-sitter::tree-sitter
          $<$<PLATFORM_ID:Linux>:Threads::Threads> # 使用生成器表达式
)

if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  target_compile_options(
    ${PROJECT_NAME} PRIVATE -Wall -Wextra -Wpedantic $<$<CONFIG:Debug>:-g -O0>
                            $<$<CONFIG:Release>:-O3>)
endif()