cmake_minimum_required(VERSION 4.0)

project(tsl-server)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

message(STATUS "CMAKE_CXX_COMPILER_ID: ${CMAKE_CXX_COMPILER_ID}")
message(STATUS "CMAKE_SYSTEM_NAME: ${CMAKE_SYSTEM_NAME}")
message(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")

if(DEFINED CMAKE_TOOLCHAIN_FILE)
  message(STATUS ">>> CMAKE_TOOLCHAIN_FILE: ${CMAKE_TOOLCHAIN_FILE}")
endif()
if(DEFINED VCPKG_TARGET_TRIPLET)
  message(STATUS ">>> VCPKG_TARGET_TRIPLET: ${VCPKG_TARGET_TRIPLET}")
endif()

# 设置默认构建类型
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  set(CMAKE_BUILD_TYPE
      "Release"
      CACHE STRING "Build type" FORCE)
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
                                               "MinSizeRel" "RelWithDebInfo")
endif()

# MinGW/MSYS2 静态链接
if(MINGW)
  add_link_options(-static -static-libgcc -static-libstdc++)
elseif(UNIX AND NOT APPLE) # Linux 静态链接
  add_link_options(-static-libgcc -static-libstdc++)
endif()

if(WIN32)
  set(CMAKE_FIND_LIBRARY_SUFFIXES ".a" ".lib" ".dll.a")
else()
  set(CMAKE_FIND_LIBRARY_SUFFIXES ".a" ".so")
endif()

find_package(glaze CONFIG REQUIRED)
find_package(spdlog CONFIG REQUIRED)
find_package(fmt CONFIG REQUIRED)
find_package(Taskflow REQUIRED)

if(UNIX AND NOT APPLE)
  find_package(Threads REQUIRED)
endif()

if(DEFINED CMAKE_TOOLCHAIN_FILE)
  find_package(unofficial-tree-sitter CONFIG REQUIRED)
  set(TREESITTER_TARGET unofficial::tree-sitter::tree-sitter)
else()
  # find_package(PkgConfig REQUIRED) pkg_check_modules(TREESITTER tree-sitter)
  find_library(TREESITTER_LIBRARY tree-sitter) # use ${TREESITTER_LIBRARY}
  set(TREESITTER_TARGET ${TREESITTER_LIBRARY})
endif()

if(NOT TARGET spdlog::spdlog_header_only)
  message(WARNING "spdlog header-only target not found, using shared library")
endif()
if(NOT TARGET fmt::fmt-header-only)
  message(WARNING "fmt header-only target not found, using shared library")
endif()

include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src)
set(SOURCES
    src/main.cpp
    src/utils/args_parser.cpp
    src/utils/string.cpp
    src/core/dispacther.cpp
    src/core/server.cpp
    src/scheduler/async_executor.cpp
    src/language/ast/deserializer.cpp
    src/language/ast/detail.cpp
    src/language/ast/tree_sitter_utils.cpp
    src/language/symbol/builder.cpp
    src/language/symbol/location_index.cpp
    src/language/symbol/relations.cpp
    src/language/symbol/store.cpp
    src/language/symbol/scope.cpp
    src/language/symbol/table.cpp
    src/language/symbol/builder.cpp
    src/language/keyword/repo.cpp
    src/provider/base/bootstrap.cpp
    src/provider/base/interface.cpp
    src/provider/initialize/initialize.cpp
    src/provider/initialized/initialized.cpp
    src/provider/text_document/did_open.cpp
    src/provider/text_document/did_change.cpp
    src/provider/text_document/did_close.cpp
    src/provider/text_document/completion.cpp
    # src/provider/text_document/semantic_tokens.cpp
    src/provider/shutdown/shutdown.cpp
    src/provider/exit/exit.cpp
    src/provider/cancel_request/cancel_request.cpp
    src/provider/trace/set_trace.cpp
    src/provider/completion_item/resolve.cpp
    src/service/base/bootstrap.cpp
    src/service/utils/text_coordinates.cpp
    src/service/detail/document/text_document.cpp
    src/service/detail/symbol/conversion.cpp
    src/service/detail/symbol/repository/editing.cpp
    src/service/detail/symbol/repository/workspace.cpp
    src/service/detail/symbol/repository/system.cpp
    src/service/document.cpp
    src/service/symbol.cpp
    src/service/parser.cpp
    src/tree-sitter/parser.c
    src/tree-sitter/scanner.c)

add_executable(${PROJECT_NAME} ${SOURCES})
target_include_directories(${PROJECT_NAME} PRIVATE src)

target_compile_definitions(${PROJECT_NAME} PRIVATE SPDLOG_HEADER_ONLY
                                                   FMT_HEADER_ONLY)

target_link_libraries(
  ${PROJECT_NAME}
  PRIVATE glaze::glaze Taskflow::Taskflow spdlog::spdlog_header_only
          fmt::fmt-header-only ${TREESITTER_TARGET} # 使用变量，避免条件判断
          $<$<PLATFORM_ID:Linux>:Threads::Threads> # 使用生成器表达式
)

if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  target_compile_options(
    ${PROJECT_NAME} PRIVATE -Wall -Wextra -Wpedantic $<$<CONFIG:Debug>:-g -O0>
                            $<$<CONFIG:Release>:-O3>)
endif()